Difference between revisions of "SPARQL"

Latest revision as of 11:23, 28 April 2024

Draft

December 2021 rewriting : work in progress, please do not translate yet.

NOW/Opened: General content review. You may help by: a) reading and copy-editing the page's English, b) testing queries on LLQS, edit in or discuss improvements, ~~3) increase comments' concistency~~.
Legend: 🇶 minor aspects to improve, see hidden comment ; ❌ query too heavy to run in this page.
Later/not yet: translations.

Help welcome.

Base

Useful elements

Special:ListProperties – exhaustive list of LinguaLibre's Wikibase properties.
LinguaLibre:List of languages – exhaustive list of LinguaLibre's languages

... Loading ...

Tools

On Wikidata, the WDQS allows to practice SPARQL queries creation in an intuitive way.

Endpoint LinguaLibre LinguaLibre Query Service (LLQS) – run SPARQL Queries upon LinguaLibre. Run, test, download the data as json, csv or tsv.
Endpoint Wikidata Wikidata Query Service (WDQS) – run SPARQL Queries upon Wikidata. Run, test, download the data as json, csv or tsv. Has advanced user-friendly features such as : word hovering too see a term's meaning, code optimization, etc.
Endpoint Wikimedia Commons Wikimedia Commons Query Service (WCQS) run SPARQL Queries upon Wikimedia Commons wikibase (need to log in).
Wikidata Lexeme Queries generators (hack me) by @sina_ahm – helps to create queries for Wikidata's Lexeme.
Special:ApiSandbox – API queries generator for Lingualibre wikipage and wikibase contents. An alternative to SPARQL queries.

References

Code snippets

Fetch data using SPARQL

LinguaLibre data can be fetched using various coding languages such as Python, Javascript, R and others, returning JSON or other formats.

For code snippet in your language : open query.wikidata.org (WikiData Query Service, aka WDQS), run your SPARQL query, click "Code" : a pop up window appears with various implementations.
For downloading data, click "Download".

Javascript:
At least 3 methods exists (code snippet), example:

Query

Result's basic unit

SPARQL:

SELECT ?item WHERE { ?item prop:P2 entity:Q5 } LIMIT 10

{ … },
{
  "item": {
    "type": "uri",
    "value": "https://lingualibre.org/entity/Q12"
  },
  "itemLabel": {
    "xml:lang": "en",
    "type": "literal",
    "value": "beginner"
  }
},
{ … }

Javascript:

var endpoint = 'https://lingualibre.org/sparql';
var sparql = 'SELECT ?item WHERE { ?item prop:P2 entity:Q5 } LIMIT 10';
$.getJSON(endpoint,
	{ query: sparql, format: 'json' },
	function(data){ console.log('JQuery: ',data)}
);

Merging data

Advanced SPARQL queries with COUNT() and others are often slow (>3secs, sometime >100secs). You are encouraged to do multiple smaller SPARQL queries to then merge their responded data. By example, the complementary Javascript snippet below would help web developers to do so.

// Data from 3 sparql queries.
// Important: One key must be similar in all datasets, here: 'qid'
const langs = [{ qid: 'Q209', label: 'Breton', iso:'bre' }, { qid: 'Q34', label: 'Marathi', iso: 'mar' }],
    speakersFemales = [{ qid: 'Q209', genderF: 3, recordsF: 60 }, { qid: 'Q34', genderF: 21, recordsF:5046 }],
    speakersMales = [{ qid: 'Q209', genderM: 7, recordsM: 218 }, { qid: 'Q34', genderM: 85, recordsM:32964 }];
// Toolbox for merging data by same id
var merge2ArraysBySameId = function(arr1,arr2,id1){
	return arr1.map( item1 => { 
  	var identical = arr2.find(obj => obj[id1] === item1[id1]); 
  	return Object.assign(identical, item1) 
  } );
}
// Mergings
var step1 = merge2ArraysBySameId(langs,speakersFemales,'qid');
var step2 = merge2ArraysBySameId(step1,speakersMales,'qid');
alert(JSON.stringify(step2))

Lingualibre's ground

Is Language (d:Q34770) → List existing languages with: LL Qid, ISO 639-3, Name

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?lang ?iso ?langLabel
WHERE {
  # First get the relevant languages by first looking up all records
  {
    SELECT DISTINCT ?lang WHERE {
      _:record wdt:P31 wd:Q108167708 ; # Filter to get wd:Q108167708 (pronunciation file)
               wdt:P407 ?lang .        # For each pronunciation file, fetch the language
    }
  }
  
  # From this point on, ?lang is bound. Get the label and ISO code on Wikidata
  SERVICE <https://query.wikidata.org/sparql> {
    ?lang wdt:P31 wd:Q34770 .  # Filter: P31 'instance of' is Q1193409 'language or dialect'.
    ?lang wdt:P220 ?iso .      # Assign value: P220 'ISO-639-3' into ?iso.
  }

  SERVICE wikibase:label {
    # Add label to each variable used.
    # ?lang now has twin variable ?langLabel
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Is Speaker (speaker (Q3)) → List existing speakers

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?speaker ?speakerLabel
WHERE {
  ?speaker prop:P2 entity:Q3 .  # Filter: P2 'instance of' is Q3 'speaker'.
  # Add labels to each variable used.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Is Language level (language level (Q5)) → List existing levels

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?item ?itemLabel
WHERE {
  ?item prop:P2 entity:Q5    # Filter: P2 'instance of' is Q5 'language level'.
  # Add labels to each variable used.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Is Sex or Gender (sex or gender (Q7)) → List existing sexes or genders

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?item ?itemLabel
WHERE {
  ?item prop:P2 entity:Q7    # Filter: P2 'instance of' is Q7 'sex or gender'.
  # Add labels to each variable used.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Speaker

🇶 Speaker name(s) → Speaker Qid(s)

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?speakerName ?speakerId
WHERE {
  VALUES ?speakerName { "Yug" "VIGNERON" } # Assign value: one or multiple values
  # note: need to comment BIND
  BIND ( STRLANG(?speakerName, "en") AS ?speakerLabel )
  # Grammatical note: ';' allows to chain actions 
  ?speakerId prop:P2 entity:Q3 ;        # Filter: P2 'instance of' is Q3 'speaker'.
             rdfs:label ?speakerLabel . # Filter by value: label equal ?speakerLabel's value
}

... Loading ...

🇶 Speaker Qid (SangeetaRH (Q445757)) → Speaker data, all

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
# Get Q445757 (User:SangeetaRH‎)'s data
SELECT ?anyProperty ?anyValue ?anyValueLabel
WHERE {
  entity:Q445757 ?anyProperty ?anyValue .  # Filter: of Q445757 'SangeetaRH‎', get any property and any values
  # Add labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

🇶 Speaker Qid (SangeetaRH (Q445757)) → Speaker languages (P4)

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?languages ?languagesLabel
WHERE {
  entity:Q445757 prop:P4 ?languages . # Assign value: for Q445757 'SangeetaRH‎', P4 'language' into ?languages
  # Add labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

🇶 Count speaker gender (P8)

#defaultEndpoint:Lingualibre
SELECT ?genderLabel (count(?speaker) AS ?nb)
WHERE {
  ?speaker prop:P2 entity:Q3 ;
           prop:P8 ?gender .
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}
GROUP BY ?genderLabel

... Loading ...

Speaker Qid (speakers/1 ???) + Language LL Qid (d:Q1571) → List records

This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.

#defaultEndpoint:Commons
SELECT ?audio ?audioLabel
WHERE {
  ?audio wdt:SPEAKER_PROPERTY_MISSING <http://lingualibre.org/speakers/1> ; # Filter: ??? 'speaker' P5 Speaker is User:SangeetaRH
         wdt:P407 wd:Q1571 .   # Filter: P407 'language' is Q1571 'Marathi'
  
  # Add labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Speaker Qid (speakers/1 ???) + Language LL Qid (d:Q1571) → Count records

This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.

#defaultEndpoint:Commons
SELECT ?language ?speaker (COUNT(?audio) AS ?audio)
WHERE {
  # Comment out the below pattern to filter by language, e.g. Q1571 or others
  # VALUES ?language { wd:Q1571 }  # Bind value: Q1571 'Marathi' into ?language
  VALUES ?speaker { <http://lingualibre.org/speakers/1> }   # Assign value: ll.org/speakers/1 (for 'SangeetaRH') into ?speaker
  
  ?audio wdt:SPEAKER_PROPERTY_MISSING ?speaker ; # Filter: ??? 'speaker' is ?speaker
         wdt:P407 ?language ;                    # Filter: P407 'language' bound to ?language
         wdt:P31 wd:Q108167708 .                 # Filter: P31 'instance of' is Q108167708 'pronunciation file'
}
GROUP BY ?language ?speaker  # Sorting first groups per language and speaker

... Loading ...

Is Speaker (speaker (Q3)) → List of accounts and associated speakers

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?linkedUser ?speakerLabel (SUBSTR(STR(?speaker),32) AS ?speakerQid)
WHERE {
  ?speaker prop:P2 entity:Q3 .  # Filter: P2 'instance of' is Q3 'speaker'.
  ?speaker prop:P11 ?linkedUser . # Assign value: P11 'linked users' into ?linkedUser.
  # Add labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
} ORDER BY DESC (?speakerLabel)

... Loading ...

Languages

🇶 LL Language (Q930) → List of words recorded

This query could be run on Wikimedia Commons MediaWiki API. See Help:APIs.

#defaultEndpoint:Wikidata
PREFIX prop: <https://lingualibre.org/prop/direct/>
PREFIX entity: <https://lingualibre.org/entity/>
SELECT ?writing WHERE {
  SERVICE <https://lingualibre.org/sparql> {
    SELECT ?writing WHERE {
      ?record prop:P2 entity:Q2;
        prop:P4 entity:Q930, ?language;
        prop:P3 ?url;
        prop:P7 ?writing.
    # FILTER(CONTAINS(STR(?audio), "LL-Q35735")) # occitan
      SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
    }
  }
}

... Loading ...

🇶 Language name(s) in English → Language LL Qid(s)

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?languageId ?languageName 
WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    VALUES ?languageName { "Marathi" "Atikamekw" "Central Bikol" } # Target values
    
    BIND ( STRLANG(?languageName, "en") AS ?languageLabel ) # Bind filter by English
    
    ?languageId rdfs:label ?languageLabel ;  # Assign value label into ?languageLabel
                wdt:P31 wd:Q34770 .          # Filter: P2 'instance of' is Q4 'language' AND
    
  }
}

... Loading ...

Language ISO-639-3 → Language LL Qid(s), Wikidata Qid, Label

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?langIso ?langId ?langIdLabel
WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    VALUES ?langIso { "mar" "bre" "bcl" "atj" "ban" } # Target ISO values
    ?langId 
      wdt:P220 ?langIso ;    # Assign value: P13 'Iso-639-3' to ?langIso AND
      wdt:P31 wd:Q34770 ;    # Filter: P2 'instance of' is Q4 'language' 

  }

  # Labels
  SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"}
}

... Loading ...

Language LL All Languages → Count records

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?language ?languageLabel ?audios WHERE {
  { 
    SELECT ?language (COUNT(?audio) AS ?audios) WHERE {
    # Comment out the below statement to filter to only certain languages (e.g. Q34 or others)
    # VALUES ?language { entity:Q34 }

    ?audio wdt:P31 wd:Q108167708 ;  # Filter: P2 'instance of' is Q2 'record'
           wdt:P407 ?language .
  }
   GROUP BY ?language
  }

  SERVICE <https://query.wikidata.org/sparql> {
    SERVICE wikibase:label { 
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
      ?language rdfs:label ?languageLabel .
    }
  }
}

... Loading ...

🇶 Language LL All Languages → Count unique words, audios, ratio

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?language ?languageLabel ?words ?audios ?percent
WHERE {
  {
    SELECT ?language
           (COUNT(DISTINCT(?itemLabel)) AS ?words)  # Count and assign value to ?Audio
           (COUNT(?audio) as ?audios) 
           (ROUND(10000*?words/?audios)/100 AS ?percent)
           WHERE {
             # Uncomment the below line to filter languages (e.g Q34 or others)
             # VALUES ?language { wd:Q34 }
             ?audio wdt:P407 ?language ;      # Bind property P407 'language' to ?language
                    wdt:P31 wd:Q108167708 ;   # Filter: P31 'instance of' Q108167708 (pronunciation file)
                    wdt:P9533 ?itemLabel .   # Bind P9533 'transcription' to ?itemLabel.
           }
    GROUP BY ?language ?languageLabel
  }

 
    SERVICE <https://query.wikidata.org/sparql> {
      SERVICE wikibase:label { 
        bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
        ?language rdfs:label ?languageLabel .
      }
  }
}

... Loading ...

Language LL All Languages → Count speakers

This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.

#defaultEndpoint:Commons
SELECT ?language ?languageLabel ?speakers WHERE {
  {
    SELECT ?language (COUNT(?speaker) AS ?speakers) WHERE {

      # Uncomment the below line to filter to specific languages
      # E.g Q34 and others
      # VALUES ?language { wd:Q34 }

      ?record wdt:P407 ?language ;                    # Bind P407 'language' to ?language (if unbound)
              wdt:P31 wd:Q108167708 ;                 # P31 'instance of' Q108167708 'pronunciation file'
              wdt:SPEAKER_PROPERTY_MISSING ?speaker ; # Bind ??? 'speaker' to ?speaker
    } GROUP BY ?language
  }
  
  SERVICE <https://query.wikidata.org/sparql> {
    SERVICE wikibase:label { 
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
      ?language rdfs:label ?languageLabel
    }
  }
}

... Loading ...

Language LL Qid (Q209) → List speakers

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT ?language ?speaker ?speakerLabel WHERE {
  VALUES ?language { entity:Q209 }
  ?speaker prop:P2 entity:Q3 .  # P2 'instance of' is Q3 'speaker'
  ?speaker prop:P4 ?language .  # P4 'language' is Q34 'Marathi'
  # Labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Language LL Qid (d:Q12107) → Language data, all

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?predicate ?object WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    # Given Q12107 language, get all properties and values
    wd:Q12107 ?predicate ?object .
  }
}

... Loading ...

Language LL Qid (d:Q12107) → Language data, Literals

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT * WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    # Given Q12107 'Breton language', get only literals
    wd:Q12107 ?predicate ?object .
    ?predicate rdf:type owl:DatatypeProperty .
  }
}

... Loading ...

Language LL Qid (d:Q12107) → Property P220 (ISO 639-3)

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT * WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    wd:Q12107 wdt:P220 ?iso . # Assign value : Q209 'Breton', P13 'ISO 639-3', value into ?iso
  }
}

... Loading ...

Languages → List existing languages' iso-639-3

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT * WHERE {
  SERVICE <https://query.wikidata.org/sparql> {
    ?lang wdt:P220 ?code .
  }
}

... Loading ...

🇶 Language WD Qid → Language data, core

This query is going to be DEPRECATED as the queried data will no longer be available.

#defaultEndpoint:Lingualibre
SELECT * WHERE {
  ?lang prop:P12 "Q12107" .  # Filter: P12 'Wikidata id' is Wikidata's "Q12107"
  ?lang ?predicate ?object . # 
  ?predicate rdf:type owl:DatatypeProperty .
}

... Loading ...

Records

Record LL Qid (sdc:M69288741) → Record data, all

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT * WHERE {
  sdc:M69288741 ?predicate ?object .
}

... Loading ...

Record LL Qid (sdc:M69288741) → Record data, core

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT * WHERE {
  sdc:M69288741 ?predicate ?object .

  SERVICE <https://query.wikidata.org/sparql> {
    ?predicate rdf:type owl:DatatypeProperty . 
  } 
}

... Loading ...

Language (d:Q1860) + String → Record LL Qid(s)

This query has been UPDATED to work on Commons SPARQL Endpoint.

#defaultEndpoint:Commons
SELECT ?item
WHERE { 
  ?item wdt:P31 wd:Q108167708 . # Filter: P31 'instance of' Q108167708 'record'
  ?item wdt:P407 wd:Q1860 .     # Filter: P407 'language' is Q1860 'English'
  ?item wdt:P9533 "apple"@en.   # Filter: P9533 'transcription' is "apple"
}

... Loading ...

Language (d:Q12107) + Speaker (/speakers/1 ??) + String (ni) → Record LL Qid

This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.

Case: Search in Breton language, with speaker 'ThonyVezbe',

SELECT ?audio ?urlPointer
WHERE {
  ?audio wdt:P407 wd:Q12107 ;                                                # P407 'language' is Q12107 'Breton'
         wdt:SPEAKER_PROPERTY_MISSING <https://lingualibre.org/speakers/1> ; # ??? 'speaker' is ll.org/speakers/1 'ThonyVezbe'
         wdt:P9533 "ni"@br ;
         schema:url ?urlPointer .
}

... Loading ...

Language (d:Q150) + Speaker (/speakers/1 ??) + String → URL pointer, filename

This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.

SELECT ?audio ?urlPointer
  (REPLACE(REPLACE(REPLACE(SUBSTR(STR(?urlPointer),52),"%20","_"),"%28","("),"%29",")") AS ?filename)
WHERE {
  ?audio wdt:P407 wd:Q150 ;                                                   # Filter: P407 'language' is Q150 'French'
         wdt:SPEARKER_PROPERTY_MISSING <https://lingualibre.org/speakers/1> ; # Filter: ??? 'speaker' is ll.org/speakers/1 'Aemines1'
         wdt:P9533 "pomme"@fr ; # Filter: P9533 'audio transcription' of "pomme" in French
         schema:url ?urlPointer # Bind the URI to the file to ?urlPointer
}

... Loading ...

Files on Commons about records in Punjabi with transcription and LinguaLibre identifier

#defaultEndpoint:Commons
SELECT * WHERE {
  ?m wdt:P31 wd:Q108167708 ; #record
     wdt:P407 wd:Q58635 ; #in Punjabi
     wdt:P9533 ?transcription ; #with transcription
     wdt:P10369 ?idLili . #with LinguaLibre identifier
}
LIMIT 100

🇶 Count records by gender of the speaker (P8)

SELECT ?genderLabel (count(?record) AS ?nb)
WHERE {
  ?record prop:P2 entity:Q2 ;
          prop:P5 ?speaker .
  ?speaker prop:P2 entity:Q3 ;
           prop:P8 ?gender .
  # Add labels to each variable used.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . } 
}
GROUP BY ?genderLabel

... Loading ...

Heavy queries

Queries below are too large to run on LinguaLibre's wikipages, or even on Lingualibre Query Service).
To do: do smaller sub-queries, with one COUNT() function.

❌ Languages → Name, Wikidata Qid, LLQid, Iso-639-3, and genders

Query

Result

#defaultEndpoint:Lingualibre
SELECT ?languageQidLabel ?wdQid ?languageQid ?isoCode 
(COUNT(DISTINCT(?record)) AS ?recordCount)
(COUNT(DISTINCT(?speakerLangM)) AS ?speakerM) 
(COUNT(DISTINCT(?speakerLangF)) AS ?speakerF)
wWHERE{
  ?record prop:P2 entity:Q2 .     # Filter: items where P2 'instance of' is Q2 'record'
  ?record prop:P4 ?languageQid .  # Assign value: P4 'language' into variable ?language
  ?languageQid prop:P12 ?wdQid .  # Assign value: P12 'wikidata id' into variable ?WD
  ?languageQid prop:P13 ?isoCode. # Assign value: P13 'iso639-3' into ?isoCode
  
  #?record prop:P5 ?speakerQidM .   # Assign value: P5 'speaker' into variable ?speakerQidM
  #?speakerQidM prop:P8 entity:Q16 .   # Filter: P8 'sex or gender' is Q16 'male
  #?speakerQidM prop:P4 ?speakerLangM .  # Assign value: P4 'language' into variable ?spakerLangM
  
  ?record prop:P5 ?speakerQidF .   # Assign value: P5 'speaker' into variable ?speakerQidF
  ?speakerQidF prop:P8 entity:Q17 .   # Filter: P8 'sex or gender' is Q17 'female
  ?speakerQidF prop:P4 ?speakerLangF .  # Assign value: P4 'language' into variable ?spakerLangF
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . } 
}
GROUP BY ?languageQidLabel ?languageQid ?wdQid ?isoCode
ORDER BY DESC(?recordCount)

#defaultEndpoint:Lingualibre
languageQidLabel	wdQid	languageQid	isoCode	recordCount	speakerM	speakerF
French	Q150	Q21	fra	16761	0	18
Marathi	Q1571	Q34	mar	13153	0	5
Polish	Q809	Q298	pol	11686	0	1
…

❌ Is Language (speaker (Q3)) → list all languages with number of unique words and speakers

#defaultEndpoint:Lingualibre
SELECT ?language (COUNT(?audio) AS ?nbAudio) (COUNT(?speaker) AS ?nbSpeaker) WHERE {
  ?language prop:P2 entity:Q4 .
  ?audio prop:P4 ?language .
  ?speaker prop:P4 ?language .
}
GROUP BY ?language

Others

(These old queries are not assessed yet.)

Language (Breton (Q209)) → Record, speaker's language level

#defaultEndpoint:Lingualibre
select ?record ?recordLabel ?speakerLabel ?languageLabel ?languageLevelLabel
where {
  ?record prop:P2 entity:Q2   # Filter: P2 'instance of' is Q2 'record' AND P4
	; prop:P4 entity:Q209 .   # AND P4 'language' is Q209 'Breton'
  ?record prop:P5 ?speaker .  # Assign value: record's P5 'speaker' into ?speaker
  ?record prop:P4 ?language . # Assign value: record's P4 'language' into ?language
  
  ?speaker llp:P4 ?languageStatement .    # P4 'language'
  ?languageStatement llv:P4 ?language .   # P4 'language'
  ?languageStatement llq:P16 ?languageLevel . # P16 'language level'
  # Adds labels
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
} ORDER BY ?languageLabel ?languageLevelLabel

... Loading ...

Language (Marathi (Q34)) → Records of Wikidata concepts with WD Qid (P12)

Those items were proposed to Lingualibre's recorder at step 3 via a SPARQL query upon Wikidata, so those words have WD's Qids.

#defaultEndpoint:Lingualibre
SELECT ?languageLabel ?recordLabel ?record ?wid
WHERE {
  ?record prop:P2 entity:Q2 .    # Filter: P2 'instance of' is Q2 'record'
  ?record prop:P4 entity:Q34 .  # Filter: P4 'language' is Q34 'Marathi'
  ?record prop:P4 ?language .    # Assign value: record's P4 'language' to variable ?language
  ?record prop:P12 ?wid .        # Assign value: record's P12 'wikidata id' to variable ?wid
  # Add labels capability
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  } 
}

... Loading ...

Records → Filter by date: late 2018

#defaultEndpoint:Lingualibre
SELECT
(COUNT(DISTINCT ?record) AS ?records)
(COUNT(DISTINCT ?speaker) AS ?speakers)
(COUNT(DISTINCT ?language) AS ?languages)
WHERE {
  ?record prop:P2 entity:Q2 .
  ?record prop:P6 ?date .
  ?record prop:P5 ?speaker .
  ?record prop:P4 ?language .
  # Filters:
  FILTER(?date >= "2018-07-01T00:00:00Z"^^xsd:dateTime 
       && ?date < "2019-01-01T00:00:00Z"^^xsd:dateTime)
}

... Loading ...

Template	{{Speakers category}} • {{Recommended lists}} • {{To iso 639-2}} • {{To iso 639-3}} • {{Userbox-records}} • {{Bot steps}}
Audio files	How to create a frequency list? • Convert files formats • Denoise files with SoX • Rename and mass rename
Bots	Help:Bots • LinguaLibre:Bot • Help:Log in to Lingua Libre with Pywikibot • Lingua Libre Bot (gh) • Olafbot • PamputtBot • Dragons Bot (gh)
MediaWiki	MediaWiki: Help:Documentation opérationelle Mediawiki • Help:Database structure • Help:CSS • Help:Rename • Help:OAuth • LinguaLibre:User rights (rate limit) • Module:Lingua Libre record & {{Lingua Libre record}} • JS scripts: MediaWiki:Common.js • LastAudios.js • SoundLibrary.js • ItemsSugar.js • LexemeQueriesGenerator.js (pad) • Sparql2data.js (pad) • LanguagesGallery.js (pad) • Gadgets: Gadget-LinguaImporter.js • Gadget-Demo.js • Gadget-RecentNonAudio.js • LiLiZip.js
Queries	Help:APIs • Help:SPARQL • SPARQL (intermediate) (stub) • SPARQL for lexemes (stub) • SPARQL for maintenance • Lingualibre:Wikidata (stub) • Help:SPARQL (HAL)
Reuses	Help:Download datasets • Help:Embed audio in HTML
Unstable & tests	Help:SPARQL/test
Categories	Category:Technical reports

@@ Line 117: / Line 117: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?lang ?iso ?langLabel
 WHERE {
@@ Line 142: / Line 143: @@
 ||
 <query _pagination="5" >
+#defaultEndpoint:Commons
 SELECT ?lang ?iso ?langLabel
 WHERE {
@@ Line 173: / Line 175: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?speaker ?speakerLabel
 WHERE {
@@ Line 184: / Line 187: @@
 ||
 <query _pagination="5" speaker="Item" speakerLabel="Speaker" langLabel="Language">
+#defaultEndpoint:Lingualibre
 SELECT ?speaker ?speakerLabel
 WHERE {
@@ Line 201: / Line 205: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?item ?itemLabel
 WHERE {
@@ Line 212: / Line 217: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Lingualibre
 SELECT ?item ?itemLabel
 WHERE {
@@ Line 229: / Line 235: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?item ?itemLabel
 WHERE {
@@ Line 240: / Line 247: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Lingualibre
 SELECT ?item ?itemLabel
 WHERE {
@@ Line 259: / Line 267: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?speakerName ?speakerId
 WHERE {
@@ Line 272: / Line 281: @@
 <query _pagination="5">
+#defaultEndpoint:Lingualibre
 SELECT ?speakerName ?speakerId
 WHERE {
@@ Line 289: / Line 299: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 # Get Q445757 (User:SangeetaRH‎)'s data
 SELECT ?anyProperty ?anyValue ?anyValueLabel
@@ Line 301: / Line 312: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Lingualibre
 SELECT ?anyProperty ?anyValue ?anyValueLabel
 WHERE {
@@ Line 319: / Line 331: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?languages ?languagesLabel
 WHERE {
@@ Line 330: / Line 343: @@
 ||
 <query _pagination="5" >
+#defaultEndpoint:Lingualibre
 SELECT ?languages ?languagesLabel
 WHERE {
@@ Line 338: / Line 352: @@
    }
 }
+</query>
+|}
+=== 🇶 Count speaker gender ([[Property:P8|P8]]) ===
+<!-- Q: Add languages iso P:13 -->
+{| style="width:100%"
+|- style="vertical-align:top;"
+|style="padding: 0 3em;width:60%"|
+<syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
+SELECT ?genderLabel (count(?speaker) AS ?nb)
+WHERE {
+  ?speaker prop:P2 entity:Q3 ;
+           prop:P8 ?gender .
+  SERVICE wikibase:label {
+    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
+  }
+}
+GROUP BY ?genderLabel
+</syntaxhighlight>
+||
+<query _pagination="5" >
+#defaultEndpoint:Lingualibre
+SELECT ?genderLabel (count(?speaker) AS ?nb)
+WHERE {
+  ?speaker prop:P2 entity:Q3 ;
+           prop:P8 ?gender .
+  SERVICE wikibase:label {
+    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
+  }
+}
+GROUP BY ?genderLabel
 </query>
 |}
@@ Line 347: / Line 394: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?audio ?audioLabel
 WHERE {
@@ Line 360: / Line 408: @@
 ||
 <query _pagination="5" >
+#defaultEndpoint:Commons
 SELECT ?audio ?audioLabel
 WHERE {
@@ Line 379: / Line 428: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?language ?speaker (COUNT(?audio) AS ?audio)
 WHERE {
@@ Line 392: / Line 442: @@
 </syntaxhighlight>
 |
-<query _pagination="6" item="Property" itemLabel="Values">SELECT ?language ?speaker (COUNT(?audio) AS ?audio)
+<query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Commons
+SELECT ?language ?speaker (COUNT(?audio) AS ?audio)
 WHERE {
    # Comment out the below pattern to filter by language.
@@ Line 414: / Line 466: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?linkedUser ?speakerLabel (SUBSTR(STR(?speaker),32) AS ?speakerQid)
 WHERE {
@@ Line 426: / Line 479: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Lingualibre
 SELECT ?linkedUser ?speakerLabel (SUBSTR(STR(?speaker),32) AS ?speakerQid)
 WHERE {
@@ Line 439: / Line 493: @@
 == Languages ==
+=== 🇶 LL Language (Q930) → List of words recorded ===
+''This query could be run on Wikimedia Commons MediaWiki API. See [[Help:APIs]].''
+<!-- Q: Change exact match by CONTAINS() -->
+{| style="width:100%"
+|- style="vertical-align:top;"
+|style="padding: 0 3em;width:60%"|
+<syntaxhighlight lang="sparql">
+#defaultEndpoint:Wikidata
+PREFIX prop: <https://lingualibre.org/prop/direct/>
+PREFIX entity: <https://lingualibre.org/entity/>
+SELECT ?writing WHERE {
+  SERVICE <https://lingualibre.org/sparql> {
+    SELECT ?writing WHERE {
+      ?record prop:P2 entity:Q2;
+        prop:P4 entity:Q930, ?language;
+        prop:P3 ?url;
+        prop:P7 ?writing.
+    # FILTER(CONTAINS(STR(?audio), "LL-Q35735")) # occitan
+      SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
+    }
+  }
+}
+</syntaxhighlight>
+||
+<query _pagination="5">
+#defaultEndpoint:Wikidata
+PREFIX prop: <https://lingualibre.org/prop/direct/>
+PREFIX entity: <https://lingualibre.org/entity/>
+SELECT ?writing WHERE {
+  SERVICE <https://lingualibre.org/sparql> {
+    SELECT ?writing WHERE {
+      ?record prop:P2 entity:Q2;
+        prop:P4 entity:Q930, ?language;
+        prop:P3 ?url;
+        prop:P7 ?writing.
+    # FILTER(CONTAINS(STR(?audio), "LL-Q35735")) # occitan
+      SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
+    }
+  }
+}
+</query>
+|}
 === 🇶 Language name(s) in English → Language LL Qid(s) ===
 ''This query has been UPDATED to work on Commons SPARQL Endpoint. ''
@@ Line 446: / Line 543: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?languageId ?languageName
 WHERE {
@@ Line 461: / Line 559: @@
 ||
 <query _pagination="5">
+#defaultEndpoint:Commons
 SELECT ?languageId ?languageName
 WHERE {
@@ Line 482: / Line 581: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?langIso ?langId ?langIdLabel
 WHERE {
@@ Line 498: / Line 598: @@
 ||
 <query _pagination="5" >
+#defaultEndpoint:Commons
 SELECT ?langIso ?langId ?langIdLabel
 WHERE {
@@ Line 520: / Line 621: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?language ?languageLabel ?audios WHERE {
    {
@@ Line 542: / Line 644: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Commons
 SELECT ?language ?languageLabel ?audios WHERE {
    {
@@ Line 571: / Line 674: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
-SELECT ?language ?languageLabel ?words ?audios ?percent WHERE {
+#defaultEndpoint:Commons
+SELECT ?language ?languageLabel ?words ?audios ?percent
+WHERE {
    {
      SELECT ?language
@@ Line 598: / Line 703: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
-SELECT ?language ?languageLabel ?words ?audios ?percent WHERE {
+#defaultEndpoint:Commons
+SELECT ?language ?languageLabel ?words ?audios ?percent
+WHERE {
    {
      SELECT ?language
@@ Line 631: / Line 738: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?language ?languageLabel ?speakers WHERE {
    {
@@ Line 655: / Line 763: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Commons
 SELECT ?language ?languageLabel ?speakers WHERE {
    {
@@ Line 685: / Line 794: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?language ?speaker ?speakerLabel WHERE {
    VALUES ?language { entity:Q209 }
@@ Line 697: / Line 807: @@
 |
 <query _pagination="6" item="Property" itemLabel="Values">
+#defaultEndpoint:Lingualibre
 SELECT ?language ?speaker ?speakerLabel WHERE {
    VALUES ?language { entity:Q209 }
@@ Line 714: / Line 825: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?predicate ?object WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 723: / Line 835: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Commons
 SELECT ?predicate ?object WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 738: / Line 851: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 748: / Line 862: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 764: / Line 879: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 772: / Line 888: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 786: / Line 903: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 794: / Line 912: @@
 ||
 <query _pagination="5" >
+#defaultEndpoint:Commons
 SELECT * WHERE {
    SERVICE <https://query.wikidata.org/sparql> {
@@ Line 809: / Line 928: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT * WHERE {
    ?lang prop:P12 "Q12107" .  # Filter: P12 'Wikidata id' is Wikidata's "Q12107"
@@ Line 817: / Line 937: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Lingualibre
 SELECT * WHERE {
    ?lang prop:P12 "Q12107" .
@@ Line 833: / Line 954: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    sdc:M69288741 ?predicate ?object .
@@ Line 839: / Line 961: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Commons
 SELECT * WHERE {
    sdc:M69288741 ?predicate ?object .
@@ Line 851: / Line 974: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    sdc:M69288741 ?predicate ?object .
@@ Line 861: / Line 985: @@
 ||
 <query _pagination="10" >
+#defaultEndpoint:Commons
 SELECT * WHERE {
    sdc:M69288741 ?predicate ?object .
@@ Line 877: / Line 1,002: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT ?item
 WHERE {
@@ Line 886: / Line 1,012: @@
 ||
 <query _pagination="5">
+#defaultEndpoint:Commons
 SELECT ?item
 WHERE {
@@ Line 895: / Line 1,022: @@
 |}
-=== Language ([[wd:Q12107]]) + Speaker (/speakers/1 ??) + String (ni) → Record LL Qid ===
+=== Language ([[d:Q12107]]) + Speaker (/speakers/1 ??) + String (ni) → Record LL Qid ===
 ''This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.''
@@ Line 954: / Line 1,081: @@
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Commons
 SELECT * WHERE {
    ?m wdt:P31 wd:Q108167708 ; #record
@@ Line 962: / Line 1,090: @@
 LIMIT 100
 </syntaxhighlight>
+=== 🇶 Count records by gender of the speaker ([[Property:P8|P8]]) ===
+{| style="width:100%"
+|- style="vertical-align:top;"
+|style="padding: 0 3em;width:60%"|
+<syntaxhighlight lang="sparql">
+SELECT ?genderLabel (count(?record) AS ?nb)
+WHERE {
+  ?record prop:P2 entity:Q2 ;
+          prop:P5 ?speaker .
+  ?speaker prop:P2 entity:Q3 ;
+           prop:P8 ?gender .
+  # Add labels to each variable used.
+  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
+}
+GROUP BY ?genderLabel
+</syntaxhighlight>
+||
+<query _pagination="5" >
+SELECT ?genderLabel (count(?record) AS ?nb)
+WHERE {
+  ?record prop:P2 entity:Q2 ;
+          prop:P5 ?speaker .
+  ?speaker prop:P2 entity:Q3 ;
+           prop:P8 ?gender .
+  # Add labels to each variable used.
+  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
+}
+GROUP BY ?genderLabel
+GROUP BY ?genderLabel
+</query>
+|}
 == Heavy queries ==
@@ Line 974: / Line 1,135: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?languageQidLabel ?wdQid ?languageQid ?isoCode
 (COUNT(DISTINCT(?record)) AS ?recordCount)
@@ Line 999: / Line 1,161: @@
 ||
 <pre>
+#defaultEndpoint:Lingualibre
 languageQidLabel	wdQid	languageQid	isoCode	recordCount	speakerM	speakerF
 French	Q150	Q21	fra	16761	0	18
@@ Line 1,009: / Line 1,172: @@
 === ❌ Is Language ([[Q3]]) → list all languages with number of unique words and speakers ===
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?language (COUNT(?audio) AS ?nbAudio) (COUNT(?speaker) AS ?nbSpeaker) WHERE {
    ?language prop:P2 entity:Q4 .
@@ Line 1,025: / Line 1,189: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 select ?record ?recordLabel ?speakerLabel ?languageLabel ?languageLevelLabel
 where {
@@ Line 1,043: / Line 1,208: @@
 ||
 <query _pagination="5">
+#defaultEndpoint:Lingualibre
 select ?record ?recordLabel ?speakerLabel ?languageLabel ?languageLevelLabel
 where {
@@ Line 1,067: / Line 1,233: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT ?languageLabel ?recordLabel ?record ?wid
 WHERE {
@@ Line 1,081: / Line 1,248: @@
 ||
 <query _pagination="5">
+#defaultEndpoint:Lingualibre
 SELECT ?languageLabel ?recordLabel ?record ?wid
 WHERE {
@@ Line 1,100: / Line 1,268: @@
 |style="padding: 0 3em;width:60%"|
 <syntaxhighlight lang="sparql">
+#defaultEndpoint:Lingualibre
 SELECT
+(COUNT(DISTINCT ?record) AS ?records)
 (COUNT(DISTINCT ?speaker) AS ?speakers)
-(COUNT(DISTINCT ?record) AS ?records)
+(COUNT(DISTINCT ?language) AS ?languages)
 WHERE {
    ?record prop:P2 entity:Q2 .
    ?record prop:P6 ?date .
    ?record prop:P5 ?speaker .
+  ?record prop:P4 ?language .
    # Filters:
-   FILTER(?date >= "2018-07-01T00:00:00Z"^^xsd:dateTime)
+   FILTER(?date >= "2018-07-01T00:00:00Z"^^xsd:dateTime
-  FILTER(?date < "2019-01-01T00:00:00Z"^^xsd:dateTime)
+       && ?date < "2019-01-01T00:00:00Z"^^xsd:dateTime)
 }
 </syntaxhighlight>
 ||
 <query>
+#defaultEndpoint:Lingualibre
 SELECT
+(COUNT(DISTINCT ?record) AS ?records)
 (COUNT(DISTINCT ?speaker) AS ?speakers)
-(COUNT(DISTINCT ?record) AS ?records)
+(COUNT(DISTINCT ?language) AS ?languages)
 WHERE {
    ?record prop:P2 entity:Q2 .
    ?record prop:P6 ?date .
    ?record prop:P5 ?speaker .
+  ?record prop:P4 ?language .
    # Filters:
-   FILTER(?date >= "2018-07-01T00:00:00Z"^^xsd:dateTime)
+   FILTER(?date >= "2018-07-01T00:00:00Z"^^xsd:dateTime
-  FILTER(?date < "2019-01-01T00:00:00Z"^^xsd:dateTime)
+       && ?date < "2019-01-01T00:00:00Z"^^xsd:dateTime)
 }
 </query>
@@ Line 1,130: / Line 1,304: @@
 == See also ==
 * [[Help:SPARQL 2]] — next tutorial with focus on federate queries and Wikidata Lexemes.
-** [[:wikidata:Lexicographical data/Ideas of queries|Lexicographical data/Ideas of queries]]
+** [[d:Wikidata:Lexicographical data/Ideas of queries|Lexicographical data/Ideas of queries]]
 ** [[LinguaLibre:Wikidata]] — stub, help write it !
 * [[Help:Querying Lingua Libre]] — general review, redirecting users to rightful place.
@@ Line 1,136: / Line 1,310: @@
 * [[:mw:Manual:Developing extensions]] — PHP-based modules enhancing wikis, can pull data via SPARQL queries.
-{{Lingua Libre scripts}}
+{{Technicals}}
 [[Category:Lingua Libre:Help{{#translation:}}]]