Help

SPARQL (HAL)

Éléments notables

Propriétés notables : HAL

ItemLabel WD Qid sur WD sur HAL
HAL Q3144107 -- --
HAL author ID `P4450` 1,816 127,727?
HAL structure ID `P6773` 5,950 35,992
HAL article ID `P7864` 716 1,199,139
HAL journal ID `P8903` 29,733 113,000+?
  • Manque de réconciliation

Propriétés notables : Articles `P7864`

ItemLabel WD Qid
title `P1476`
author / author name string `P50` / `P2093`
publication date `P577`
published in `P14233`
volume `P478`
issue `P433`
page(s) `P304`
main subject `P921`

Propriétés notables : Revues `P8903`

ItemLabel WD Qid
inception `P571`
title `P1476`
main subject `P921`
country of origin `P495`

Propriétés notables : Auteurs `P4450`

ItemLabel WD Qid
sex or gender `P21`
date of birth `P569`
place of birth `P19`
country of citizenship `P27`
given name `P735`
doctoral advisor `P184`
doctoral student `P185`
occupation P106

Propriétés notables : Structures `P6773`

ItemLabel WD Qid
inception `P571`
title `P1476`
main subject `P921`
country `P17`
coordinate location `P625`
parent organization `P749`
official website `P856`
ROR ID `P6782`

✅ HAL Authors

✅ Number of people in Wikidata with HAL Authors ID (P4450)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Authors_In_Wikidata)
WHERE {
  ?item wdt:P4450 ?halIdValue. 
}
... Loading ...


✅ HAL Authors on Wikidata → birthdate

#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue ?genderLabel (YEAR(?birthDate) AS ?birthYear)
WHERE {
  ?item wdt:P31 wd:Q5.                       # is human (Q5)
  ?item wdt:P4450 ?halIdValue.               # HAL author ID `P4450` in ?halIdValue
  OPTIONAL { ?item wdt:P569 ?birthDate. }    # birthDate `P569` in ?birthDate
  # MINUS { ?item wdt:P569 ?birthDate. }
  OPTIONAL { ?item wdt:P21 ?gender. }        # gender `P21` in ?gender
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?birthYear)
... Loading ...

✅ HAL Authors on Wikidata → Authors cv, publications

#defaultEndpoint:Wikidata
SELECT ?item
?itemLabel 
 (ENCODE_FOR_URI(?itemLabel) AS ?uriLabel)  # Wikipedia title
?halIdValue
 (CONCAT("https://cv.hal.science/", STR(?halIdValue)) AS ?halAuthorCv)  #
 (CONCAT("<a href=https://hal.science/search/index/q/*/authIdHal_s/", STR(?halIdValue),">link</a>") AS ?halAuthorPublications)
 (CONCAT("https://api.archives-ouvertes.fr/search/?q=authIdHal_s:", STR(?halIdValue),'&wt=json') AS ?halAuthorPublicationsAPI)
WHERE {
  ?item wdt:P31 wd:Q5.                       # has HAL author ID `P4450`
  ?item wdt:P4450 ?halIdValue.               # HAL author ID `P4450` in ?halIdValue
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?itemLabel)
... Loading ...

✅ HAL Authors on Wikidata → Authors per gender (P21)

1814 authors HAL author ID with in wikipedia

#defaultEndpoint:Wikidata
SELECT 
?genderLabel (count(?item) AS ?nb)           # counting gender
WHERE {
  ?item wdt:P31 wd:Q5;                       # is instance of P31 human `Q5`
        wdt:P4450 ?halIdValue.               # HAL author ID `P4450` in ?halIdValue
  OPTIONAL { ?item wdt:P21 ?gender. }        # gender `P21` in ?gender
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?genderLabel
... Loading ...

✅ HAL Articles

#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?value
{
  ?item wdt:P7864 ?dbvalue.
  BIND(IF(wikibase:isSomeValue(?dbvalue), "", ?dbvalue) AS ?value)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
... Loading ...

✅ Number of items in Wikidata with `HAL article ID` property (P7864 )

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Article_ID_In_Wikidata)
WHERE {
  ?item wdt:P7864 ?halIdValue. 
}
... Loading ...

✅ Number of items in Wikidata with `HAL Article ID` property (P7864) but no creation date (P571)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Article_ID_In_Wikidata)
WHERE {
  ?item wdt:P7864 ?halIdValue. 
  MINUS { ?item wdt:P571 ?creationDate. }
}
... Loading ...

✅ HAL Article → creation date (inception)

#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue
(YEAR(?publicationDate) AS ?publicationYear) 
?publishedIn ?pages
(GROUP_CONCAT(?authorLabel1 ; separator=" | ") as ?authorsList)
WHERE {
  ?item wdt:P7864 ?halIdValue .
  OPTIONAL { ?item wdt:P1476 ?title }          # title `P1476`
  OPTIONAL { ?item wdt:P577 ?publicationDate } # publication date `P577`
  OPTIONAL { ?item wdt:P14233 ?publishedIn }   # published in `P14233`
  OPTIONAL { ?item wdt:P304 ?pages }           # pages `P304`
  OPTIONAL { ?item wdt:P2093 ?author }           # author `P50`
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  
  BIND(CONCAT(UCASE(SUBSTR(?author, 1 , 1 )), SUBSTR(?author, 2 )) AS ?authorLabel1)
}
GROUP BY ?item ?itemLabel ?halIdValue ?publicationDate ?publishedIn ?pages
... Loading ...

✅ HAL Journals

✅ Number of items in Wikidata with `HAL journal ID` property (P8903)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Jounal_ID_In_Wikidata)
WHERE {
  ?item wdt:P8903 ?halIdValue. 
}
... Loading ...

✅ Number of items in Wikidata with `HAL journal ID` property(P48903) but no creation date (P571)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Jounal_ID_In_Wikidata)
WHERE {
  ?item wdt:P8903 ?halIdValue. 
  MINUS { ?item wdt:P571 ?creationDate. }
}
... Loading ...

✅ HAL Journal → creation date (inception)

#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue (YEAR(?creationDate) AS ?creationYear)
WHERE {
  ?item wdt:P8903 ?halIdValue.
  OPTIONAL { ?item wdt:P571 ?creationDate. }
  # MINUS { ?item wdt:P571 ?creationDate. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?creationYear)
... Loading ...

🇶 HAL Journal on Wikidata per country (P495)

#defaultEndpoint:Wikidata
SELECT 
?countryLabel (count(?item) AS ?nb)           # counting occurence per country
WHERE {
  ?item wdt:P8903 ?halIdValue.               # HAL journal ID `P8903` in ?halIdValue
  OPTIONAL { ?item wdt:P495 ?country }       # country of origin `P495`
  # OPTIONAL { ?item wdt:P921 ?topic }       # main subject `P921` 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?countryLabel
ORDER BY DESCC (?nb)
... Loading ...

✅ HAL Structures

✅ Number of items in Wikidata with `HAL structure ID` property (P6773)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Structure_ID_In_Wikidata)
WHERE {
  ?item wdt:P6773 ?halIdValue. 
}
... Loading ...

✅ Number of items in Wikidata with `HAL structure ID` property(P6773) but no creation date (P571)

#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Structure_ID_In_Wikidata)
WHERE {
  ?item wdt:P6773 ?halIdValue. 
  MINUS { ?item wdt:P571 ?creationDate. }
}
... Loading ...

✅ HAL Structure → creation date (inception P571) and country (P17)

#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue (YEAR(?creationDate) AS ?creationYear) ?countryLabel
WHERE {
  ?item wdt:P6773 ?halIdValue.
  OPTIONAL { ?item wdt:P571 ?creationDate. }
  OPTIONAL { ?item wdt:P17 ?country }       # country `P17`
  # MINUS { ?item wdt:P571 ?creationDate. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?countryLabel)
... Loading ...

🇶 HAL Structures on Wikidata per country of origin (P495)

5942 structures HAL author ID with in Wikidata

#defaultEndpoint:Wikidata
SELECT 
?countryLabel (count(?item) AS ?nb)           # counting occurence per country
WHERE {
  ?item wdt:P6773 ?halIdValue.               # HAL structure ID `P6773` in ?halIdValue
  OPTIONAL { ?item wdt:P495 ?country }       # country of origin `P495`
  # OPTIONAL { ?item wdt:P921 ?topic }       # main subject `P921` 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?countryLabel
ORDER BY DESCC (?nb)
... Loading ...

🇶 HAL Structures on Wikidata per country (P17)

5942 structures HAL author ID with in Wikidata

#defaultEndpoint:Wikidata
SELECT 
?countryLabel (count(?item) AS ?nb)           # counting occurence per country
WHERE {
  ?item wdt:P6773 ?halIdValue.               # HAL structure ID `P6773` in ?halIdValue
  OPTIONAL { ?item wdt:P17 ?country }        # country `P17`
  # OPTIONAL { ?item wdt:P921 ?topic }       # main subject `P921` 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?countryLabel
ORDER BY DESC (?nb)
... Loading ...

Structures on Wikidata -> authors -> with HAL author id

5942 structures HAL author ID with in Wikidata

#defaultEndpoint:Wikidata
#defaultEndpoint:Wikidata
SELECT ?item ?halIdValue ?genderLabel (YEAR(?birthDate) AS ?birthYear) WHERE {
  VALUES ?structure {
    # wd:Q1194988 # Paris 8
    # wd:Q13531686 # Paris Saclays
    wd:Q20669873 # University of Toulouse
        wd:Q1933558  # University Toulouse - Jean Jaurès
        wd:Q1273188  # Toulouse III University - Paul-Sabatier
        wd:Q51784003 # Toulouse Mirail
    wd:Q64716811 # PRES University of Toulouse
  }
  ?item wdt:P31 wd:Q5 ;
        wdt:P108 ?structure .
  OPTIONAL { ?item wdt:P4450 ?halIdValue } # halIdValue -> 64 
  OPTIONAL { ?item wdt:P569 ?birthDate. }
  OPTIONAL { ?item wdt:P21 ?gender. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
ORDER BY DESC (?birthYear)
... Loading ...

Work to come

See also

Help page:

HAL SPARQL

HAL API:

Wikidata SPARQL

Federation request:

Wiki HAL

Lingua Libre technical helps
Template {{Speakers category}} • {{Recommended lists}} • {{To iso 639-2}} • {{To iso 639-3}} • {{Userbox-records}} • {{Bot steps}}
Audio files How to create a frequency list?Convert files formatsDenoise files with SoXRename and mass rename
Bots Help:BotsLinguaLibre:BotHelp:Log in to Lingua Libre with PywikibotLingua Libre Bot (gh) • OlafbotPamputtBotDragons Bot (gh)
MediaWiki MediaWiki: Help:Documentation opérationelle MediawikiHelp:Database structureHelp:CSSHelp:RenameHelp:OAuthLinguaLibre:User rights (rate limit) • Module:Lingua Libre record & {{Lingua Libre record}}JS scripts: MediaWiki:Common.jsLastAudios.jsSoundLibrary.jsItemsSugar.jsLexemeQueriesGenerator.js (pad) • Sparql2data.js (pad) • LanguagesGallery.js (pad) • Gadgets: Gadget-LinguaImporter.jsGadget-Demo.jsGadget-RecentNonAudio.js
Queries Help:APIsHelp:SPARQLSPARQL (intermediate) (stub) • SPARQL for maintenance (stub) • Lingualibre:Wikidata (stub) • Help:SPARQL (HAL)
Reuses Help:Download datasetsHelp:Embed audio in HTML
Unstable & tests Help:SPARQL/test
Categories Category:Technical reports