Help
Difference between revisions of "SPARQL (HAL)"
| Line 335: | Line 335: | ||
== Work to come == | == Work to come == | ||
<!-- | <!-- | ||
| + | |||
=== 🇶 Author name(s) → Author Qid(s) === | === 🇶 Author name(s) → Author Qid(s) === | ||
''This query is going to be DEPRECATED as the queried data will no longer be available.'' | ''This query is going to be DEPRECATED as the queried data will no longer be available.'' | ||
Revision as of 22:08, 14 June 2023
✅ HAL Authors
✅ Number of people in Wikidata with HAL Authors ID (P4450)
#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Authors_In_Wikidata)
WHERE {
?item wdt:P4450 ?halIdValue.
}
|
|
✅ HAL Authors on Wikidata → birthdate
#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue ?genderLabel (YEAR(?birthDate) AS ?birthYear)
WHERE {
?item wdt:P31 wd:Q5. # has HAL author ID `P4450`
?item wdt:P4450 ?halIdValue. # HAL author ID `P4450` in ?halIdValue
OPTIONAL { ?item wdt:P569 ?birthDate. } # birthDate `P569` in ?birthDate
# MINUS { ?item wdt:P569 ?birthDate. }
OPTIONAL { ?item wdt:P21 ?gender. } # gender `P21` in ?gender
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?birthYear)
|
|
✅ HAL Authors on Wikidata → Authors cv, publications
#defaultEndpoint:Wikidata
SELECT ?item
?itemLabel
(ENCODE_FOR_URI(?itemLabel) AS ?uriLabel) # Wikipedia title
?halIdValue
(CONCAT("https://cv.hal.science/", STR(?halIdValue)) AS ?halAuthorCv) #
(CONCAT("https://hal.science/search/index/q/*/authIdHal_s/", STR(?halIdValue)) AS ?halAuthorPublications)
(CONCAT("https://api.archives-ouvertes.fr/search/?q=authIdHal_s:", STR(?halIdValue),'&wt=json') AS ?halAuthorPublicationsAPI)
WHERE {
?item wdt:P31 wd:Q5. # has HAL author ID `P4450`
?item wdt:P4450 ?halIdValue. # HAL author ID `P4450` in ?halIdValue
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?itemLabel)
|
|
✅ HAL Authors on Wikidata → Authors per gender (P21)
1814 authors HAL author ID with in wikipedia
#defaultEndpoint:Wikidata
SELECT
?genderLabel (count(?item) AS ?nb) # counting gender
WHERE {
?item wdt:P31 wd:Q5; # has HAL author ID `P4450`
wdt:P4450 ?halIdValue. # HAL author ID `P4450` in ?halIdValue
OPTIONAL { ?item wdt:P21 ?gender. } # gender `P21` in ?gender
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?genderLabel
|
|
✅ HAL Articles
SELECT ?item ?itemLabel ?value {
?item wdt:P7864 ?dbvalue.
BIND(IF(wikibase:isSomeValue(?dbvalue), "", ?dbvalue) AS ?value)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
✅ Number of items in Wikidata with `HAL article ID` property (P7864 )
#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Article_ID_In_Wikidata)
WHERE {
?item wdt:P7864 ?halIdValue.
}
|
|
✅ Number of items in Wikidata with `HAL Article ID` property (P7864) but no creation date (P571)
#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Article_ID_In_Wikidata)
WHERE {
?item wdt:P7864 ?halIdValue.
MINUS { ?item wdt:P571 ?creationDate. }
}
|
|
✅ HAL Article → creation date (inception)
#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue
(YEAR(?publicationDate) AS ?publicationYear)
?publishedIn ?pages
(GROUP_CONCAT(?authorLabel1 ; separator=" | ") as ?authorsList)
WHERE {
?item wdt:P7864 ?halIdValue .
OPTIONAL { ?item wdt:P1476 ?title } # title `P1476`
OPTIONAL { ?item wdt:P577 ?publicationDate } # publication date `P577`
OPTIONAL { ?item wdt:P14233 ?publishedIn } # published in `P14233`
OPTIONAL { ?item wdt:P304 ?pages } # pages `P304`
OPTIONAL { ?item wdt:P2093 ?author } # author `P50`
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
BIND(CONCAT(UCASE(SUBSTR(?author, 1 , 1 )), SUBSTR(?author, 2 )) AS ?authorLabel1)
}
GROUP BY ?item ?itemLabel ?halIdValue ?publicationDate ?publishedIn ?pages
|
|
✅ HAL Journals
✅ Number of items in Wikidata with `HAL journal ID` property (P48903)
#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Jounal_ID_In_Wikidata)
WHERE {
?item wdt:P8903 ?halIdValue.
}
|
|
✅ Number of items in Wikidata with `HAL journal ID` property(P48903) but no creation date (P571)
#defaultEndpoint:Wikidata
SELECT (COUNT(?item) AS ?number_Of_Hal_Jounal_ID_In_Wikidata)
WHERE {
?item wdt:P8903 ?halIdValue.
MINUS { ?item wdt:P571 ?creationDate. }
}
|
|
✅ HAL Journal → creation date (inception)
#defaultEndpoint:Wikidata
SELECT ?item ?itemLabel ?halIdValue (YEAR(?creationDate) AS ?creationYear)
WHERE {
?item wdt:P8903 ?halIdValue.
OPTIONAL { ?item wdt:P571 ?creationDate. }
# MINUS { ?item wdt:P571 ?creationDate. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?creationYear)
|
|
🇶 HAL authors on Wikidata per gender (P21)
1814 authors HAL author ID with in wikipedia
#defaultEndpoint:Wikidata
SELECT
?genderLabel (count(?item) AS ?nb) # counting gender
WHERE {
?item wdt:P31 wd:Q5; # has HAL author ID `P4450`
wdt:P4450 ?halIdValue. # HAL author ID `P4450` in ?halIdValue
OPTIONAL { ?item wdt:P21 ?gender. } # gender `P21` in ?gender
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?genderLabel
|
|
Work to come
#defaultEndpoint:Lingualibre
SELECT ?speakerName ?speakerId
WHERE {
VALUES ?speakerName { "Yug" "VIGNERON" } # Assign value: one or multiple values
# note: need to comment BIND
BIND ( STRLANG(?speakerName, "en") AS ?speakerLabel )
# Grammatical note: ';' allows to chain actions
?speakerId prop:P2 entity:Q3 ; # Filter: P2 'instance of' is Q3 'speaker'.
rdfs:label ?speakerLabel . # Filter by value: label equal ?speakerLabel's value
}
|
|
🇶 Speaker Qid (SangeetaRH (Q445757)) → Speaker data, all
This query is going to be DEPRECATED as the queried data will no longer be available.
#defaultEndpoint:Lingualibre
# Get Q445757 (User:SangeetaRH)'s data
SELECT ?anyProperty ?anyValue ?anyValueLabel
WHERE {
entity:Q445757 ?anyProperty ?anyValue . # Filter: of Q445757 'SangeetaRH', get any property and any values
# Add labels
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
}
|
|
🇶 Speaker Qid (SangeetaRH (Q445757)) → Speaker languages (P4)
This query is going to be DEPRECATED as the queried data will no longer be available.
#defaultEndpoint:Lingualibre
SELECT ?languages ?languagesLabel
WHERE {
entity:Q445757 prop:P4 ?languages . # Assign value: for Q445757 'SangeetaRH', P4 'language' into ?languages
# Add labels
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
}
|
|
Speaker Qid (speakers/1 ???) + Language LL Qid (d:Q1571) → List records
This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.
#defaultEndpoint:Commons
SELECT ?audio ?audioLabel
WHERE {
?audio wdt:SPEAKER_PROPERTY_MISSING <http://lingualibre.org/speakers/1> ; # Filter: ??? 'speaker' P5 Speaker is User:SangeetaRH
wdt:P407 wd:Q1571 . # Filter: P407 'language' is Q1571 'Marathi'
# Add labels
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
}
|
|
Speaker Qid (speakers/1 ???) + Language LL Qid (d:Q1571) → Count records
This query is IN WORK for Commons SPARQL Endpoint. One Wikidata property is missing; please update this query with the right property URI.
#defaultEndpoint:Commons
SELECT ?language ?speaker (COUNT(?audio) AS ?audio)
WHERE {
# Comment out the below pattern to filter by language, e.g. Q1571 or others
# VALUES ?language { wd:Q1571 } # Bind value: Q1571 'Marathi' into ?language
VALUES ?speaker { <http://lingualibre.org/speakers/1> } # Assign value: ll.org/speakers/1 (for 'SangeetaRH') into ?speaker
?audio wdt:SPEAKER_PROPERTY_MISSING ?speaker ; # Filter: ??? 'speaker' is ?speaker
wdt:P407 ?language ; # Filter: P407 'language' bound to ?language
wdt:P31 wd:Q108167708 . # Filter: P31 'instance of' is Q108167708 'pronunciation file'
}
GROUP BY ?language ?speaker # Sorting first groups per language and speaker
|
|
Is Speaker (speaker (Q3)) → List of accounts and associated speakers
This query is going to be DEPRECATED as the queried data will no longer be available.
#defaultEndpoint:Lingualibre
SELECT ?linkedUser ?speakerLabel (SUBSTR(STR(?speaker),32) AS ?speakerQid)
WHERE {
?speaker prop:P2 entity:Q3 . # Filter: P2 'instance of' is Q3 'speaker'.
?speaker prop:P11 ?linkedUser . # Assign value: P11 'linked users' into ?linkedUser.
# Add labels
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
} ORDER BY DESC (?speakerLabel)
|
|